Polygonal Line Path

static class Path implements Iterable<PVector>
{

  private ArrayList<PVector> points = new ArrayList<PVector>();

  private ArrayList<IPathListener> listeners = new ArrayList<IPathListener>();

  public int length() {
    return points.size();
  }

  public boolean isEmpty() {
    return points.size() == 0;
  }

  public PVector point(int i) {
    return points.get(i);
  }

  public PVector lastPoint() {
    return points.get(points.size() - 1);
  }

  public void addPoint(PVector p) {
    points.add(p);
    for (IPathListener listener : listeners)
      listener.onAddPoint(this, p);
  }

  public void addPoint(float x, float y) {
    addPoint(new PVector(x, y));
  }

  public void clear() {
    points.clear();
    for (IPathListener listener : listeners)
      listener.onClear(this);
  }

  public void addListener(IPathListener listener) {
    listeners.add(listener);
  }

  public Iterator<PVector> iterator() {
    return points.iterator();
  }
}

interface IPathListener
{

  void onAddPoint(Path sender, PVector p);

  void onClear(Path sender);
}